Ping: sensor de distância por ultrassom

Ping))) é o nome de um sensor de distância por ultrassom da Parallax. Ele detecta a distância do objeto mais próximo à sua frente, até uma distância máxima de 3 m. Ele fica a enviar rajadas de ultrassom e a escutar o eco causado pela reflexão das ondas que colidem em um objeto. O Arduino envia um pequeno pulso elétrico para engatilhar a deteção e, depois, fica a observar se há o retorno de um pulso no mesmo pino. A duração desse segundo pulso é igual ao tempo gasto pela onda sonora ir até o objeto, refletir e retornar ao Ping))). Como sabemos a velocidade do som, calculamos a distância.

Circuito

O pino de 5V do Ping))) é ligado aos 5V do Arduino, o GND ao GND (duh) e o pino SIG ao pino digital 7 do Arduino.

Código

int pingPin = 7;

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  long duration, inches, cm;

  // O PING))) é engatilhado por meio de um pulso HIGH de 2 ou mais microssegundos.
  // Põe-se um pulso LOW de antemão para que o pulso de HIGH seja evidente.
  pinMode(pingPin, OUTPUT);
  digitalWrite(pingPin, LOW);
  delayMicroseconds(2);
  digitalWrite(pingPin, HIGH);
  delayMicroseconds(5);
  digitalWrite(pingPin, LOW);

  // O mesmo pino é usado para ler o sinal do PING))): um pulso
  //  HIGH cuja duração é o tempo (em microssegundos) desde o envio
  // da rajada sonora até o retorno do eco
  pinMode(pingPin, INPUT);
  duration = pulseIn(pingPin, HIGH);

  // converta o tempo para distância
  inches = microsecondsToInches(duration);
  cm = microsecondsToCentimeters(duration);

  Serial.print(inches);
  Serial.print("in, ");
  Serial.print(cm);
  Serial.print("cm");
  Serial.println();

  delay(100);
}

long microsecondsToInches(long microseconds)
{
  // De acordo com a folha de dados da Parallax, há
  // 73.746 microssegundos por polegada (o som viaja a 1130 pés por
  // segundo). Isto dá a distância viajada pela rajada sonora, ricochetear e
  // retornar, de forma que dividimos por 2 para obter a distância até o obstáculo.
  // Veja: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
  return microseconds / 74 / 2;
}

long microsecondsToCentimeters(long microseconds)
{
  // A velocidade do som é 340 m/s ou 29 microssegundos por centímetro.
  // A rajada sonora vai e volta, portanto, para achar a distância até o
  // objeto, tomamos metade da distância de viagem.
  return microseconds / 29 / 2;
}

Share